romanoflash

TankiOnline

Romano — Mon, 06 Jul 2009 17:07:06 +0000

Сфера из плейнов Alternativa 3D

Romano — Wed, 03 Jun 2009 18:49:02 +0000

Когда начал думать над реализацией сайта, то в начале было это:

Сфера из плейнов, при наведение на плейн происходит анимация и обратно.

Контроллер камеры активен: w,a,s,d, spacebar, z.

Ниже код:

package
{
import alternativa.engine3d.controllers.CameraController;
import alternativa.engine3d.core.Camera3D;
import alternativa.engine3d.core.Object3D;
import alternativa.engine3d.core.Scene3D;
import alternativa.engine3d.display.View;
import alternativa.engine3d.events.MouseEvent3D;
import alternativa.engine3d.materials.FillMaterial;
import alternativa.engine3d.primitives.Plane;
import alternativa.engine3d.primitives.Sphere;
import alternativa.types.Point3D;
import alternativa.utils.FPS;
import caurina.transitions.Tweener;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.net.navigateToURL;
import flash.net.URLRequest;
 
/**
* ...
* @author Romano (www.romano.su)
*/
public class SpherePlane extends Sprite
{
private var scene:Scene3D;
private var view:View;
private var camera:Camera3D;
private var sphere:Sphere;
 
private var r:Number = 100;
// кол-во плейнов по вертикали
private var numV:Number = 12;
// кол-во плейнов по гор-ли
private var numH:Number = 12;
 
private var cameraController:CameraController;
 
private var offsetPlane:Number = 1.5;
 
[Embed(source = "../assets/alternativa3d_medium.png")]
private var Logo:Class;
 
public function SpherePlane():void
{
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
 
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
 
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
 
// Создание сцены
scene = new Scene3D();
scene.root = new Object3D();
 
// Добавление камеры и области вывода
camera = new Camera3D();
camera.z = 200;
camera.x = 400;
scene.root.addChild(camera);
 
view = new View();
addChild(view);
view.camera = camera;
view.interactive = true;
 
// Создание сферы из плейнов
// i - плейны по вертикали
// j - плейны по гор-ли
for (var i:int = 0; i &lt; numV; i++)
{
for (var j:int = 0; j &lt; numH ; j++)
{
// делим 180 градусов на кол-во плейнов, прибавляем половину от этого к результату, чтобы плейны распределялись равномерно
var a1:Number = i * (180/numV) + (180/numV)/2;
var a2:Number = j * (360/numH);
var angle1:Number = (a1 * Math.PI / 180);
var angle2:Number = (a2 * Math.PI / 180);
 
// ширина и высота плейна в зависимости от расположения по вертикали
var sc:Number = Math.sin(angle1)*15;
 
var plane:Plane = new Plane(sc, sc);
 
plane.cloneMaterialToAllSurfaces(new FillMaterial(0xFFFFFF,0.5));
 
plane.x = r * Math.sin(angle1) * Math.cos(angle2);
plane.y = r * Math.sin(angle1) * Math.sin(angle2);
plane.z = r * Math.cos(angle1);
 
plane.rotationZ = angle2 + Math.PI/2;
plane.rotationX = angle1;
 
scene.root.addChild(plane);
 
plane.addEventListener(MouseEvent3D.MOUSE_OVER, planeOver);
}
}
 
// Подключение контроллера камеры
cameraController = new CameraController(stage);
cameraController.camera = camera;
cameraController.setDefaultBindings();
cameraController.checkCollisions = true;
cameraController.collisionRadius = 20;
cameraController.lookAt(new Point3D(0, 0, 0));
cameraController.controlsEnabled = true;
 
// Запуск счётчика кадров
FPS.init(stage);
 
stage.addEventListener(Event.RESIZE, onResize);
stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
insertLogo();
 
onResize(null);
}
 
private function planeOver(event:MouseEvent3D):void
{
var selectObj:Plane = event.currentTarget as Plane;
selectObj.mouseEnabled = false;
Tweener.addTween(selectObj, {x: selectObj.x*offsetPlane, y: selectObj.y*offsetPlane, z: selectObj.z*offsetPlane, rotationX: selectObj.rotationX + Math.PI, time:1, onComplete: completeTween,  onCompleteParams:[event], transition:"easeInSine"  } );
}
 
private function completeTween(event:MouseEvent3D):void {
var selectObj:Plane = event.currentTarget as Plane;
Tweener.addTween(event.currentTarget, { x: selectObj.x/offsetPlane, y: selectObj.y/offsetPlane, z: selectObj.z/offsetPlane, rotationX: selectObj.rotationX - Math.PI, time:1,  onComplete: enablePlane,  onCompleteParams:[event], transition:"easeOutSine"} );
}
 
private function enablePlane(event:MouseEvent3D):void
{
var selectObj:Plane = event.currentTarget as Plane;
selectObj.mouseEnabled = true;
}
 
private function onResize(e:Event):void {
view.width = stage.stageWidth;
view.height = stage.stageHeight;
}
 
private function insertLogo():void
{
var logoSprite:Sprite = new Sprite();
logoSprite.addChild(new Logo());
addChild(logoSprite);
logoSprite.x = stage.stageWidth - logoSprite.width - 5;
logoSprite.y = stage.stageHeight - logoSprite.height - 5;
logoSprite.addEventListener(MouseEvent.CLICK, function(event:MouseEvent):void {
var request:URLRequest = new URLRequest("http://www.alternativaplatform.com");
navigateToURL(request, "_blank");
});
}
 
private function onEnterFrame(event:Event):void
{
cameraController.processInput();
 
// Расчёт сцены
scene.calculate();
}
 
}
 
}

Разноцветная сфера Alternativa 3D

Romano — Mon, 23 Mar 2009 18:14:20 +0000

Грань состоит из трех точек, как минимум, а дальше создается поверхность из граней, и на нее накладывается тесктурка, как-то так. Подробнее написано тут и тут.

У сферы есть набор граней (sphere.faces) – это то что нам нужно. У каждой грани есть несколько точек, у каждой точки есть три координаты: x, y, z. При создание поверхности мы используем массив граней, а у грани уже массив точек. Чтобы добраться до граней у сферы, как я понял, надо проделать следующее:

sphere.faces.toArray(true)[i].id

true – означает индексированный массив
i – это номер элемента
id – это идентификатор грани

Далее создаем поверхность:

sphere.createSurface([sphere.faces.toArray(true)[i].id], “temp”+i);

“temp”+i – это уникальное название поверхности

И накладываем текстурку выбранной поверхносте:

sphere.setMaterialToSurface(new FillMaterial(color, 1), “temp”+i);

Исходный код ниже:

package
{
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.core.Object3D;
	import alternativa.engine3d.core.Scene3D;
	import alternativa.engine3d.display.View;
	import alternativa.engine3d.materials.FillMaterial;
	import alternativa.engine3d.primitives.Sphere;
	import alternativa.utils.FPS;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.navigateToURL;
	import flash.net.URLRequest;
 
	/**
	 * ...
	 * @author Romano (www.romano.su)
	 */
	public class ColorSphere extends Sprite
	{
		private var scene:Scene3D;
		private var view:View;
		private var camera:Camera3D;
		private var sphere:Sphere;
		private var angle1:Number;
		private var angle2:Number;
 
		private var distance:Number = 300;
 
		[Embed(source = "../assets/alternativa3d_medium.png")]
		private var Logo:Class;
 
		public function ColorSphere():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			// Создание сцены
			scene = new Scene3D();
			scene.root = new Object3D();
 
			// Добавление камеры и области вывода
			camera = new Camera3D();
			scene.root.addChild(camera);
 
			angle1 = Math.PI / 2;
			angle2 = 0;
 
			// выставляем камеру
			changeCameraCoords();
 
			view = new View();
			addChild(view);
			view.camera = camera;
			view.interactive = true;
 
			// создание сферы
			sphere = new Sphere(100, 12, 12);
			for (var i:int = 0; i &lt; sphere.faces.length; i++) {
				var color:Number = Math.random() * 0xFFFFFF;
				sphere.createSurface([sphere.faces.toArray(true)[i].id], "temp"+i);
				sphere.setMaterialToSurface(new FillMaterial(color, 1), "temp"+i);
			}
			scene.root.addChild(sphere);
 
			// Запуск счётчика кадров
			FPS.init(stage);
 
			stage.addEventListener(Event.RESIZE, onResize);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
			insertLogo();
 
			onResize(null);
		}
 
		private function changeCameraCoords():void
		{
			camera.x = distance * Math.sin(angle1) * Math.cos(angle2);
			camera.y = distance * Math.sin(angle1) * Math.sin(angle2);
			camera.z = distance * Math.cos(angle1);
 
			camera.rotationZ = angle2 + Math.PI/2;
			camera.rotationX = angle1 - Math.PI;
		}
 
		private function onResize(e:Event):void {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}
 
		private function insertLogo():void
		{
			var logoSprite:Sprite = new Sprite();
			logoSprite.addChild(new Logo());
			addChild(logoSprite);
			logoSprite.x = stage.stageWidth - logoSprite.width - 5;
			logoSprite.y = stage.stageHeight - logoSprite.height - 5;
			logoSprite.addEventListener(MouseEvent.CLICK, function(event:MouseEvent):void {
					var request:URLRequest = new URLRequest("http://www.alternativaplatform.com");
					navigateToURL(request, "_blank");
				});
		}
 
		private function onEnterFrame(event:Event):void
		{
			angle2 += Math.PI / 180;
			changeCameraCoords();
 
			// Расчёт сцены
			scene.calculate();
		}
 
	}
 
}

Вращение камеры Alternativa 3D

Romano — Mon, 23 Mar 2009 18:02:46 +0000

Способ №1:
Создать Object3D, добавить его на сцену, затем в Object3D добавить камеру и отодвинуть ее по оси z с отрицательными координатыми, в нашем случае это -300. При создание любого объекта на сцене он смотрит “лицом вверх” параллельно оси z (подробнее тут).

В итоге, получим камеру в объекте, которая удалена от центра на -300 единиц. Теперь надо повесить действие на ENTER_FRAME, в котором происходит вращение Object3D, отсюда и камера будет летать по кругу:

Ниже код:

package
{
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.core.Object3D;
	import alternativa.engine3d.core.Scene3D;
	import alternativa.engine3d.display.View;
	import alternativa.engine3d.materials.FillMaterial;
	import alternativa.engine3d.primitives.Box;
	import alternativa.utils.FPS;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.navigateToURL;
	import flash.net.URLRequest;
 
	/**
	 * ...
	 * @author Romano (www.romano.su)
	 */
	public class ObjectRotation extends Sprite
	{
		private var scene:Scene3D;
		private var view:View;
		private var camera:Camera3D;
		private var box:Box;
		private var object:Object3D;
 
		[Embed(source = "../assets/alternativa3d_medium.png")]
		private var Logo:Class;
 
		public function ObjectRotation():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			// Создание сцены
			scene = new Scene3D();
			scene.root = new Object3D();
 
			// Добавление камеры и области вывода
			camera = new Camera3D();
 
			view = new View();
			addChild(view);
			view.camera = camera;
			view.interactive = true;
 
			// создание куба
			box = new Box();
			box.cloneMaterialToAllSurfaces(new FillMaterial(0xFF0000, 1, "normal", 1, 0xFFFFFF));
			scene.root.addChild(box);
 
			// создаем объект для камеры
			object = new Object3D();
			// кидаем объект на сцену
			scene.root.addChild(object);
			// в сам объект кидаем камеру
			object.addChild(camera);
			// отодвигаем камеру на 300px
			camera.z = -300;
 
			// Запуск счётчика кадров
			FPS.init(stage);
 
			stage.addEventListener(Event.RESIZE, onResize);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
			insertLogo();
 
			onResize(null);
		}
 
		private function onResize(e:Event):void {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}
 
		private function insertLogo():void
		{
			var logoSprite:Sprite = new Sprite();
			logoSprite.addChild(new Logo());
			addChild(logoSprite);
			logoSprite.x = stage.stageWidth - logoSprite.width - 5;
			logoSprite.y = stage.stageHeight - logoSprite.height - 5;
			logoSprite.addEventListener(MouseEvent.CLICK, function(event:MouseEvent):void {
					var request:URLRequest = new URLRequest("http://www.alternativaplatform.com");
					navigateToURL(request, "_blank");
				});
		}
 
		private function onEnterFrame(event:Event):void
		{
			// вращение объекта
			object.rotationY += Math.PI/180
 
			// Расчёт сцены
			scene.calculate();
		}
 
	}
 
}

Способ №2:
Использовать сферические координаты.

Из сферической системы координат нам понадобятся только эти формула:

r ≥ 0 — расстояние от начала координат до заданной точки P.
0 ≤ θ ≤ 180° — угол между осью Z и отрезком, соединяющим начало координат и точку P.
0 ≤ φ ≤ 360° — угол между осью X и проекцией отрезка, соединяющего начало координат с точкой P, на плоскость XY

В данном примере, камера будет ездить по плоскости XY, значит угол тета будет равен 90°, т.к. в движке rotation задается в радианах, то будет Math.PI/2.

На ентер фрейме будем изменять только угол фи, чтобы камера летала по кругу вокруг куба.

Вот что имеем:

Ниже код:

package
{
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.core.Object3D;
	import alternativa.engine3d.core.Scene3D;
	import alternativa.engine3d.display.View;
	import alternativa.engine3d.materials.FillMaterial;
	import alternativa.engine3d.primitives.Box;
	import alternativa.utils.FPS;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.navigateToURL;
	import flash.net.URLRequest;
 
	/**
	 * ...
	 * @author Romano (www.romano.su)
	 */
	public class CameraRotation extends Sprite
	{
		private var scene:Scene3D;
		private var view:View;
		private var camera:Camera3D;
		private var box:Box;
		private var angle1:Number;
		private var angle2:Number;
 
		private var distance:Number = 300;
 
		[Embed(source = "../assets/alternativa3d_medium.png")]
		private var Logo:Class;
 
		public function CameraRotation():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			// Создание сцены
			scene = new Scene3D();
			scene.root = new Object3D();
 
			// Добавление камеры и области вывода
			camera = new Camera3D();
			scene.root.addChild(camera);
 
			angle1 = Math.PI / 2;
			angle2 = 0;
 
			// выставляем камеру
			changeCameraCoords();
 
			view = new View();
			addChild(view);
			view.camera = camera;
			view.interactive = true;
 
			// создание куба
			box = new Box();
			box.cloneMaterialToAllSurfaces(new FillMaterial(0xFF0000, 1, "normal", 1, 0xFFFFFF));
			scene.root.addChild(box);
 
			// Запуск счётчика кадров
			FPS.init(stage);
 
			stage.addEventListener(Event.RESIZE, onResize);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
			insertLogo();
 
			onResize(null);
		}
 
		private function changeCameraCoords():void
		{
			camera.x = distance * Math.sin(angle1) * Math.cos(angle2);
			camera.y = distance * Math.sin(angle1) * Math.sin(angle2);
			camera.z = distance * Math.cos(angle1);
 
			camera.rotationZ = angle2 + Math.PI/2;
			camera.rotationX = angle1 - Math.PI;
		}
 
		private function onResize(e:Event):void {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}
 
		private function insertLogo():void
		{
			var logoSprite:Sprite = new Sprite();
			logoSprite.addChild(new Logo());
			addChild(logoSprite);
			logoSprite.x = stage.stageWidth - logoSprite.width - 5;
			logoSprite.y = stage.stageHeight - logoSprite.height - 5;
			logoSprite.addEventListener(MouseEvent.CLICK, function(event:MouseEvent):void {
					var request:URLRequest = new URLRequest("http://www.alternativaplatform.com");
					navigateToURL(request, "_blank");
				});
		}
 
		private function onEnterFrame(event:Event):void
		{
			angle2 += Math.PI / 180;
			changeCameraCoords();
 
			// Расчёт сцены
			scene.calculate();
		}
 
	}
 
}

Программный тайлинг текстур

Romano — Wed, 18 Mar 2009 18:44:10 +0000

Если создавать модель в максе, то там же и задается тайлинг, если надо ручками, то надо умножить uv координаты на количество частей. В данном примере делаем тайлинг 2х2:

var a:Number = 2;
plane.setUVsToFace(new Point(0, 0), new Point(a, 0), new Point(a, a), "front0_0");
plane.setUVsToFace(new Point(0, 0), new Point(0, a), new Point(a, a), "back0_0");

В итоге получаем плейн с тайлингом 2х2, а также отраженные текстурки сзади:

Ниже код:

 package
{
	import alternativa.engine3d.controllers.CameraController;
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.core.Object3D;
	import alternativa.engine3d.core.Scene3D;
	import alternativa.engine3d.display.View;
	import alternativa.engine3d.materials.TextureMaterial;
	import alternativa.engine3d.primitives.Plane;
	import alternativa.types.Texture;
	import alternativa.utils.FPS;
	import fl.controls.Slider;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.net.navigateToURL;
	import flash.net.URLRequest;
 
	/**
	 * ...
	 * @author Romano (www.romano.su)
	 */
	public class Main extends Sprite
	{
		private var scene:Scene3D;
		private var view:View;
		private var camera:Camera3D;
		private var cameraController:CameraController;
		private var plane:Plane;
 
		[Embed(source = "../assets/alternativa3d_medium.png")]
		private var Logo:Class;
 
		[Embed(source = "../assets/image.png")]
		private var MyImage:Class;
 
		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			// Создание сцены
			scene = new Scene3D();
			scene.root = new Object3D();
 
			// Добавление камеры и области вывода
			camera = new Camera3D();
			camera.x = 100;
			camera.y = -150;
			camera.z = 100;
			camera.rotationX = 0;
			camera.rotationY = 0;
			camera.rotationZ = 0;
			scene.root.addChild(camera);
 
			view = new View();
			addChild(view);
			view.camera = camera;
			view.interactive = true;
 
			// создание текстуры
			var bmpImage:BitmapData = new BitmapData(400, 400);
			bmpImage.draw(new MyImage());
			var texture:Texture = new Texture(bmpImage);
			var textureMaterial:TextureMaterial = new TextureMaterial(texture, 1, true, true);
 
			// создание плейна
			plane = new Plane(100, 100);
			plane.cloneMaterialToAllSurfaces(textureMaterial);
			plane.x = 100;
			scene.root.addChild(plane);
 
			// тайлинг
			var a:Number = 2;
			plane.setUVsToFace(new Point(0, 0), new Point(a, 0), new Point(a, a), "front0_0");
			plane.setUVsToFace(new Point(0, 0), new Point(0, a), new Point(a, a), "back0_0");
 
			// Подключение контроллера камеры
			cameraController = new CameraController(stage);
			cameraController.camera = camera;
			cameraController.setDefaultBindings();
			cameraController.checkCollisions = true;
			cameraController.collisionRadius = 20;
			cameraController.lookAt(plane.coords);
 
			// Запуск счётчика кадров
			FPS.init(stage);
 
			stage.addEventListener(Event.RESIZE, onResize);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
			// создаем и добавляем слайдер на сцену
			insertSlider();
 
			insertLogo();
 
			onResize(null);
		}
 
		private function insertSlider():void
		{
			var slider:Slider = new Slider();
			slider.x = 50;
			slider.y = 50;
			slider.rotation = 90;
			slider.minimum = 0;
			slider.maximum = 360;
			slider.liveDragging = true;
			slider.snapInterval = slider.tickInterval;
			slider.addEventListener(Event.CHANGE, sliderChange);
			addChild(slider);
 
		}
 
		private function sliderChange(event:Event):void
		{
			plane.rotationX = event.currentTarget.value * (Math.PI / 180);
		}
 
		private function onResize(e:Event):void {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}
 
		private function insertLogo():void
		{
			var logoSprite:Sprite = new Sprite();
			logoSprite.addChild(new Logo());
			addChild(logoSprite);
			logoSprite.x = stage.stageWidth - logoSprite.width - 5;
			logoSprite.y = stage.stageHeight - logoSprite.height - 5;
			logoSprite.addEventListener(MouseEvent.CLICK, function(event:MouseEvent):void {
					var request:URLRequest = new URLRequest("http://www.alternativaplatform.com");
					navigateToURL(request, "_blank");
				});
		}
 
		private function onEnterFrame(event:Event):void
		{			
 
			// Расчёт сцены
			scene.calculate();
		}
 
	}
 
}

Отражение текстуры

Romano — Wed, 18 Mar 2009 18:29:48 +0000

Когда натягиваем текстурку на плейн, то видим:

Если его покрутить, то будет видно что на задней стороне плейна, текстурка лежит точно также как на фронтальной, по идее, на задней гране текстурка должна быть отражена.

Делается это с помощью переворота uv координат:

 plane.setUVsToFace(new Point(0, 0), new Point(0, 1), new Point(1, 1), "back0_0");

В итоге получим вот это:

Код ниже:

  package
{
	import alternativa.engine3d.controllers.CameraController;
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.core.Object3D;
	import alternativa.engine3d.core.Scene3D;
	import alternativa.engine3d.display.View;
	import alternativa.engine3d.materials.TextureMaterial;
	import alternativa.engine3d.primitives.Plane;
	import alternativa.types.Texture;
	import alternativa.utils.FPS;
	import fl.controls.Slider;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.net.navigateToURL;
	import flash.net.URLRequest;
 
	/**
	 * ...
	 * @author Romano (www.romano.su)
	 */
	public class Main extends Sprite
	{
		private var scene:Scene3D;
		private var view:View;
		private var camera:Camera3D;
		private var cameraController:CameraController;
		private var plane:Plane;
 
		[Embed(source = "../assets/alternativa3d_medium.png")]
		private var Logo:Class;
 
		[Embed(source = "../assets/image.png")]
		private var MyImage:Class;
 
		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			// Создание сцены
			scene = new Scene3D();
			scene.root = new Object3D();
 
			// Добавление камеры и области вывода
			camera = new Camera3D();
			camera.x = 100;
			camera.y = -150;
			camera.z = 100;
			camera.rotationX = 0;
			camera.rotationY = 0;
			camera.rotationZ = 0;
			scene.root.addChild(camera);
 
			view = new View();
			addChild(view);
			view.camera = camera;
			view.interactive = true;
 
			// создание текстуры
			var bmpImage:BitmapData = new BitmapData(400, 400);
			bmpImage.draw(new MyImage());
			var texture:Texture = new Texture(bmpImage);
			var textureMaterial:TextureMaterial = new TextureMaterial(texture, 1, true, true);
 
			// создание плейна
			plane = new Plane(100, 100);
			plane.cloneMaterialToAllSurfaces(textureMaterial);
			plane.x = 100;
			scene.root.addChild(plane);
 
			// отразили текстуру
			plane.setUVsToFace(new Point(0, 0), new Point(0, 1), new Point(1, 1), "back0_0");
 
			// Подключение контроллера камеры
			cameraController = new CameraController(stage);
			cameraController.camera = camera;
			cameraController.setDefaultBindings();
			cameraController.checkCollisions = true;
			cameraController.collisionRadius = 20;
			cameraController.lookAt(plane.coords);
 
			// Запуск счётчика кадров
			FPS.init(stage);
 
			stage.addEventListener(Event.RESIZE, onResize);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
			// создаем и добавляем слайдер на сцену
			insertSlider();
 
			insertLogo();
 
			onResize(null);
		}
 
		private function insertSlider():void
		{
			var slider:Slider = new Slider();
			slider.x = 50;
			slider.y = 50;
			slider.rotation = 90;
			slider.minimum = 0;
			slider.maximum = 360;
			slider.liveDragging = true;
			slider.snapInterval = slider.tickInterval;
			slider.addEventListener(Event.CHANGE, sliderChange);
			addChild(slider);
 
		}
 
		private function sliderChange(event:Event):void
		{
			plane.rotationX = event.currentTarget.value * (Math.PI / 180);
		}
 
		private function onResize(e:Event):void {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}
 
		private function insertLogo():void
		{
			var logoSprite:Sprite = new Sprite();
			logoSprite.addChild(new Logo());
			addChild(logoSprite);
			logoSprite.x = stage.stageWidth - logoSprite.width - 5;
			logoSprite.y = stage.stageHeight - logoSprite.height - 5;
			logoSprite.addEventListener(MouseEvent.CLICK, function(event:MouseEvent):void {
					var request:URLRequest = new URLRequest("http://www.alternativaplatform.com");
					navigateToURL(request, "_blank");
				});
		}
 
		private function onEnterFrame(event:Event):void
		{			
 
			// Расчёт сцены
			scene.calculate();
		}
 
	}
 
}

first line

Romano — Wed, 18 Mar 2009 17:55:11 +0000

Сбылась мечта, запустил блоГГгг ))

Теперь сюда буду постить все свои эксперементы и разную инфу:)))

Пока мало времени на то чтобы писать полноценные статьи, так что буду выкладывать небольшое описание и сам код