BetweenAS3.bezier(target:Object, to:Object, from:Object = null, controlPoint:Object = null, time:Number = 1.0, easing:IEasing = null);

BetweenAS3.bezierFrom(target:Object, from:Object, controlPoint:Object = null, time:Number = 1.0, easing:IEasing = null);

BetweenAS3.bezierTo(target:Object, to:Object, controlPoint:Object = null, time:Number = 1.0, easing:IEasing = null);

아래는 시작 포인트와 끝 포인트 사이에 컨트롤 포인트를 설정하고, 설정된 컨트롤 포인트 값에 의해 만들어진 베지어 곡선을 따라 트윈이 재생되는 간단한 샘플입니다.

package {

	import flash.display.Sprite;
	import flash.events.MouseEvent;

	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.tweens.ITween;

	public class BetweenAS3Bezier extends Sprite {

		private var box:Sprite;
		private var t:ITween;
		private var tg:ITween;

		private var cPointX:Array;
		private var cPointY:Array;

		public function BetweenAS3Bezier() {

			box = new Sprite();
			box.graphics.beginFill(0x000000);
			box.graphics.drawRect(-10, -10, 20, 20);
			box.graphics.endFill();
			addChild(box);
			box.x = 40;
			box.y = 40;

			cPointX = [100, 180, 280, 400];
			cPointY = [120, 20, 180, 40];

			setTween();
		}

		private function setTween() : void {
			t = BetweenAS3.bezier(box, {x:480, y:160}, {x:40, y:40}, {x:cPointX, y:cPointY}, 4);
			tg = BetweenAS3.serial(t, BetweenAS3.reverse(t));

			stage.addEventListener(MouseEvent.CLICK, hnClick);
		}

		private function hnClick(e:MouseEvent) : void {
			tg.stopOnComplete = false;
			tg.togglePause();
		}
	}
}

위치 값(x, y)뿐만 아니라 속성도 베지어 트윈이 가능하다고 합니다.
아래는 위의 소스코드에 alpha 속성에 대한 컨트롤 포인트를 적용해 보았는데, 잘 되는군요.

package {

	import flash.display.Sprite;
	import flash.events.MouseEvent;

	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.tweens.ITween;

	public class BetweenAS3Bezier extends Sprite {

		private var box:Sprite;
		private var t:ITween;
		private var tg:ITween;

		private var cAlpha:Array;
		private var cPointX:Array;
		private var cPointY:Array;

		public function BetweenAS3Bezier() {

			box = new Sprite();
			box.graphics.beginFill(0x000000);
			box.graphics.drawRect(-10, -10, 20, 20);
			box.graphics.endFill();
			addChild(box);
			box.x = 40;
			box.y = 40;

			cAlpha = [0, 0.8, 0.2, 0.5, 1];
			cPointX = [100, 180, 360, 220, 400];
			cPointY = [120, 20, 180, 150, 40];

			setTween();
		}

		private function setTween() : void {
			t = BetweenAS3.bezier(box, {alpha:1, x:480, y:160}, {alpha:0, x:40, y:40}, {alpha:cAlpha, x:cPointX, y:cPointY}, 4);
			tg = BetweenAS3.serial(t, BetweenAS3.reverse(t));

			stage.addEventListener(MouseEvent.CLICK, hnClick);
		}

		private function hnClick(e:MouseEvent) : void {
			tg.stopOnComplete = false;
			tg.togglePause();
		}
	}
}

package {

	import flash.display.Sprite;
	import flash.events.MouseEvent;

	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.betweenas3.tweens.ITween;

	public class BetweenAS3Color extends Sprite {

		private var box:Sprite;
		private var t:ITween;
		private var tg:ITween;

		public function BetweenAS3Color() {

			box = new Sprite();
			box.graphics.beginFill(0x000000);
			box.graphics.drawRect(0, 0, 200, 80);
			box.graphics.endFill();
			addChild(box);
			box.x = Math.round(stage.stageWidth * 0.5 - box.width * 0.5);
			box.y = Math.round(stage.stageHeight * 0.5 - box.height * 0.5) - 20;

			setTween();
		}

		private function setTween():void{
			t = BetweenAS3.tween(box, {transform:{colorTransform:{ redOffset:-255, greenOffset:255, blueOffset:255 }}}, null, 2, Quart.easeOut);
			tg = BetweenAS3.serial(t, BetweenAS3.reverse(t));

			stage.addEventListener(MouseEvent.CLICK, hnClick);
		}

		private function hnClick(e:MouseEvent):void	{
			tg.stopOnComplete = false;
			tg.togglePause();
		}
	}
}

사용방법은 ActionScript 3.0에서 제공되고 있는 flash.filters 패키지의 각종 클래스의 생성자 메서드와 유사한 형식으로 기술하면 됩니다.
위 색상변환 예제코드를 응용해서 간단하게 몇 가지 예를 들어보겠습니다.

– BlurFilter

private function setTween():void{
	t = BetweenAS3.tween(box, { _blurFilter:{blurX:16, blurY:16} }, null, 2, Quart.easeOut);
	tg = BetweenAS3.serial(t, BetweenAS3.reverse(t));

	stage.addEventListener(MouseEvent.CLICK, hnClick);
}

private function hnClick(e:MouseEvent):void	{
	tg.stopOnComplete = false;
	tg.togglePause();
}

– ColorMatrixFilter

private function setTween():void{
	t = BetweenAS3.tween(box,
		{ _colorMatrixFilter:{
			matrix:[
				1, 0, 0, 0, 255,
				0, 1, 0, 0, 255,
				0, 0, 1, 0, 255,
				0, 0, 0, 1, 0
				]
			}
		},
		{ _colorMatrixFilter:{
			matrix:[
				1, 0, 0, 0, -255,
				0, 1, 0, 0, -255,
				0, 0, 1, 0, -255,
				0, 0, 0, 1, 0
				]
			}
		},
		2,
		Quart.easeOut);
	tg = BetweenAS3.serial(t, BetweenAS3.reverse(t));

	stage.addEventListener(MouseEvent.CLICK, hnClick);
}

private function hnClick(e:MouseEvent):void	{
	tg.stopOnComplete = false;
	tg.togglePause();
}

– DropShadowFilter

private function setTween():void{
	box.filters = [new DropShadowFilter(4, 0, 0x000000, 0, 4, 4)];
	t = BetweenAS3.tween(box,
		{ _dropShadowFilter:{
			alpha:1,
			angle:365,
			distance:16
		} },
		{ _dropShadowFilter:{
			alpha:0,
			angle:0,
			distance:16
		} },
		2,
		Quart.easeOut);
	tg = BetweenAS3.serial(t, BetweenAS3.reverse(t));

	stage.addEventListener(MouseEvent.CLICK, hnClick);
}

private function hnClick(e:MouseEvent):void	{
	tg.stopOnComplete = false;
	tg.togglePause();
}

– GlowFilter

private function setTween():void{
	box.filters = [new GlowFilter(0x000000, 1, 0, 0, 2, 3)];
	t = BetweenAS3.tween(box,
		{ _glowFilter:{
			color:0x000000,
			alpha:1,
			blurX:16,
			blurY:16,
			strength:2
		} },
		{ _glowFilter:{
			color:0x000000,
			alpha:0,
			blurX:16,
			blurY:16,
			strength:2
		} },
		2,
		Quart.easeOut);
	tg = BetweenAS3.serial(t, BetweenAS3.reverse(t));

	stage.addEventListener(MouseEvent.CLICK, hnClick);
}

private function hnClick(e:MouseEvent):void	{
	tg.stopOnComplete = false;
	tg.togglePause();
}

1. SWF 파일이 있는 도메인(서버)과 다른 도메인(서버)에 XML 파일과 이미지파일이 있는 경우.

var url:URLRequest = new URLRequest("http://www.AAA.com/data.xml");
var loader:Loader = new Loader();
loader.load(url);

위의 소스로 문제없이 이미지파일이 로드된다.

2. SWF 파일이 있는 도메인(서버)에 XML 파일이 있고 다른 도메인(서버)에 이미지파일이 있는 경우.

이 경우 1번에서 사용한 소스로는 이미지파일이 로드되지 않는다.
이유는, LoaderContext 클래스를 매개변수로 전달하지 않아서인데…
아래 소스로 수정하면 이미지파일이 로드된다.

var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = true;
var url:URLRequest = new URLRequest("http://www.BBB.com/data.xml");
var loader:Loader = new Loader();
loader.load(url, context);

우선, 다수의 트윈을 동시에 재생하는 방법을 알아보겠습니다.
아래 무비를 클릭하면 3개의 트윈이 동시에 재생되는 것을 볼 수 있는데,

BetweenAS3.parallel()메서드를 사용하면 됩니다.
인수로는 그룹으로 만들고 싶은 트윈들을 “,” 로 구분해서 넣어주면 되고,
같은 기능을 가진 BetweenAS3.parallelTweens() 메서드의 경우는 인수가 배열형식이어야 합니다.

package {

	import flash.display.Sprite;
	import flash.events.MouseEvent;

	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.betweenas3.tweens.ITween;

	public class BetweenAS3Group extends Sprite
	{

		public function BetweenAS3Group()
		{
			stage.addEventListener(MouseEvent.CLICK, hnClick);
		}

		private function createBox($y:Number, $color:uint = 0x000000):Sprite
		{
			var box:Sprite = new Sprite();
			box.graphics.beginFill($color);
			box.graphics.drawRect(-10, -10, 20, 20);
			box.graphics.endFill();
			addChild(box);
			box.x = 20;
			box.y = $y;
			return box;
		}

		private function hnClick(e:MouseEvent):void
		{
			var box1:Sprite = createBox(20);
			var box2:Sprite = createBox(60, 0xff6600);
			var box3:Sprite = createBox(100, 0x0066ff);

			var t1:ITween = BetweenAS3.to(box1, {x:300, rotation:360}, 1.5, Bounce.easeOut);
			var t2:ITween = BetweenAS3.to(box2, {x:320, rotation:360}, 1.5, Bounce.easeOut);
			var t3:ITween = BetweenAS3.to(box3, {x:340, rotation:360}, 1.5, Bounce.easeOut);

			BetweenAS3.parallel(t1, t2, t3).play();
		}
	}
}

private function hnClick(e:MouseEvent):void
{
	var box1:Sprite = createBox(20);
	var box2:Sprite = createBox(60, 0xff6600);
	var box3:Sprite = createBox(100, 0x0066ff);

	var t1:ITween = BetweenAS3.to(box1, {x:300, rotation:360}, 1.5, Bounce.easeOut);
	var t2:ITween = BetweenAS3.to(box2, {x:320, rotation:360}, 1.5, Bounce.easeOut);
	var t3:ITween = BetweenAS3.to(box3, {x:340, rotation:360}, 1.5, Bounce.easeOut);

	BetweenAS3.serial(t1, t2, t3).play();
}

private function hnClick(e:MouseEvent):void
{
	var box1:Sprite = createBox(20);
	var box2:Sprite = createBox(60, 0xff6600);
	var box3:Sprite = createBox(100, 0x0066ff);

	var t1:ITween = BetweenAS3.to(box1, {x:300, rotation:360}, 1.5, Bounce.easeOut);
	var t2:ITween = BetweenAS3.to(box2, {x:320, rotation:360}, 1.5, Bounce.easeOut);
	var t3:ITween = BetweenAS3.to(box3, {x:340, rotation:360}, 1.5, Bounce.easeOut);

	BetweenAS3.serial(
		t1,
		BetweenAS3.serial(
			BetweenAS3.slice(t2, 0.0, 0.5, false),
			BetweenAS3.scale(BetweenAS3.slice(t2, 0.5, 1, false), 10),
			BetweenAS3.slice(t2, 1, 1.5, false)),
		BetweenAS3.serial(
			BetweenAS3.slice(t3, 0.0, 0.5, false),
			BetweenAS3.slice(t3, 0.5, 1, false)),
			BetweenAS3.scale(BetweenAS3.slice(t3, 1, 1.5, false), 10),
			BetweenAS3.reverse(t3, true),
		BetweenAS3.reverse(t2, true),
		BetweenAS3.reverse(BetweenAS3.scale(t1, 5))
	).play();
}

// tween이 종료될 때 이벤트 발생
var t:ITween = BetweenAS3.to(box, {x:280}, 1.5, Bounce.easeOut);
t.addEventListener(TweenEvent.COMPLETE, hnTweenComplete);
t.play();

private function hnTweenComplete(e:TweenEvent):void
{
    trace("TweenComplete");
}

// tween이 종료될 때 이벤트 발생(변수전달 가능)
var t:ITween = BetweenAS3.to(box, {x:280}, 1.5, Bounce.easeOut);
t.onComplete = hnTweenComplete;
t.onCompleteParams = ["param1", "param2"];
t.play();

private function hnTweenComplete(_param1:String, _param2:String):void
{
    trace(_param1, _param2);
}

아래는 스테이지를 클릭하면 작은 사각형 박스가 지정한 위치로 트윈되는 무비입니다.
하지만, 스테이지를 연속으로 클릭하면 트윈이 좀 엉성하게 재생되는 것을 볼 수 있습니다.
스테이지를 클릭할 때마다 activeMotion()함수를 호출하기 때문인데요.
YangGOON님께서 알려주신 코드가 이럴 때 유용하게 사용될 것 같네요.

public class BetweenAS3Test extends Sprite {

	private var tween:ITween;
	private var box:Sprite;

	public function BetweenAS3Test():void {
		box = new Sprite();
		box.graphics.beginFill(0x666666, 1);
		box.graphics.drawRect(-10, -10, 20, 20);
		box.graphics.endFill();
		box.x = box.y = 20;
		addChild(box);

		stage.addEventListener(MouseEvent.CLICK, hnClick);
	}

	private function hnClick(e:MouseEvent):void {
		trace("hnClick");
		activeMotion(box, 480, 80, 1);
	}

	private function activeMotion(target:Object, xPos:int, yPos:int, timeValue:Number):void {
		this.tween = BetweenAS3.tween(target, { x:xPos, y:yPos }, { x:20, y:20 }, timeValue, Cubic.easeInOut);
		this.tween.play();
	}
}

위 코드에 YangGOON님께서 알려주신 코드를 추가해 보았습니다.
activeMotion()함수가 호출될 때 지금 트윈이 재생 중인지를 체크 후 재생 중이라면 removeTween()함수를 호출합니다.
이렇게 되면 스테이지를 연속으로 클릭해도 클릭할 때마다 트윈을 처음부터 재생해 줍니다.
조금 응용한다면 트윈이 재생 중일 경우 마우스 이벤트를 막아두는 것도 방법이 되겠네요~~

public class BetweenAS3Test extends Sprite {

	private var tween:ITween;
	private var box:Sprite;

	public function BetweenAS3Test():void {
		box = new Sprite();
		box.graphics.beginFill(0x666666, 1);
		box.graphics.drawRect(-10, -10, 20, 20);
		box.graphics.endFill();
		box.x = box.y = 20;
		addChild(box);

		stage.addEventListener(MouseEvent.CLICK, hnClick);
	}

	private function hnClick(e:MouseEvent):void {
		trace("hnClick");
		activeMotion(box, 480, 80, 1);
	}

	private function activeMotion(target:Object, xPos:int, yPos:int, timeValue:Number):void {
		if (this.tween && this.tween.isPlaying) this.removeTween();

		this.tween = BetweenAS3.tween(target, { x:xPos, y:yPos }, { x:20, y:20 }, timeValue, Cubic.easeInOut);
		this.tween.play();
	}

	private function removeTween():void {
		trace("removeTween");
		this.tween.stop();
		this.tween = null;
	}
}

“Flash Professional CS5에서는 iPhone, iPod touch용 어플리케이션을 ActionScript 3을 사용해서 개발 할 수 있다.”
미국에서 열리고 있는 Adobe Max 2009 에서 오늘 아침 발표된 내용이라고 하는군요.

관련 내용은 아래 링크에서 확인할 수 있습니다.

요약해보면,
iPhone에서는 Flash가 지원되지 않습니다.(Flash Player가 설치되지 않습니다.)
그래서 Flash로 iPhone용 어플리케이션을 개발한다는 것은 불가능했었죠.
그러던 것이 Adobe가 Flash CS5에 iPhone에서 실행 가능한 형태의 파일로 컴파일해주는 기능을 추가한 것입니다.

지금 데모로 제작된 어플리케이션들을 실제 iPhone에서 실행해보면 낮은 fps로 실행된다고 하는군요. (모바일 디바이스라 어쩔 수 없나 봅니다.)
하지만 Flash에서 iPhone용 어플리케이션을 개발할 수 있다는 것은 상당히 기분 좋은 소식이네요.

Building Applications for iPhone with Flash Pro CS5

.to

// box의 x값을 현재 위치에서 280까지 이동
var t:ITween = BetweenAS3.to(box, {x:280}, 1.5, Bounce.easeOut);
t.play();

.from

// box의 x값을 280에서 현재 위치로 이동
var t:ITween = BetweenAS3.from(box, {x:280}, 1.5, Bounce.easeOut);
t.play();

.stopOnComplete

// box의 x값을 현재 위치에서 280까지 이동(무한반복)
var t:ITween = BetweenAS3.to(box, {x:280}, 1.5, Bounce.easeOut);
t.stopOnComplete = false;
t.play();

.delay

// tween을 지정한 시간만큼 지연해서 실행
var t:ITween = BetweenAS3.tween(box, {x:280}, null, 1.5, Bounce.easeOut);
BetweenAS3.delay(t, 1.0).play();

.reverse

// tween을 역으로 실행
var t:ITween = BetweenAS3.tween(box, {x:280}, null, 1.5, Bounce.easeOut);
BetweenAS3.reverse(t).play();

.scale

// tween의 스케일을 설정(4.0으로 지정했기 때문에 6초(1.5 x 4.0) 동안 tween이 실행된다.)
var t:ITween = BetweenAS3.tween(box, {x:280}, null, 1.5, Bounce.easeOut);
BetweenAS3.scale(t, 4.0).play();

.slice

// tween의 특정 부분만 실행(0.4초에서 1.2초 사이의 구간만 실행)
var t:ITween = BetweenAS3.tween(box, {x:280}, null, 1.5, Bounce.easeOut);
BetweenAS3.slice(t, 0.4, 1.2).play();

.repeat

// 해당 tween을 설정한 횟수만큼 반복해서 실행
var t:ITween = BetweenAS3.tween(box, {x:280}, null, 1.5, Bounce.easeOut);
BetweenAS3.repeat(t, 3).play();

// 위의 메서드들을 중복 실행
var t:ITween = BetweenAS3.tween(box, {x:280}, null, 1.5, Bounce.easeOut);
BetweenAS3.delay(
	BetweenAS3.repeat(
        BetweenAS3.reverse(
            BetweenAS3.scale(
                BetweenAS3.slice(t, 0.4, 1.2),
                3.0
            )
        ), 3
    ), 1
).play();

아직은 알파버전이지만, 뛰어난 퍼포먼스와 다양한 기능을 가진 BetweenerAS3 라이브러리에 대해 익혀둘 필요가 있다고 생각되어, 차근차근 익혀가면서 메모를 남겨둘까 합니다.

우선, 가장 기본적인 tween메서드의 인수에 대해 살펴보면,

BetweenAS3.tween(Target, ToValues, FromValues, Time, Easing);

• Target – 대상이 되는 오브젝트
• toValues – tween으로 적용 될 값
• fromValues – tween이 시작될 때의 값
• Time – tween이 진행되는 시간
• Easing – easing의 종류

그리고, 아래는 기본적인 Tween 적용 예입니다.

package {
	import flash.display.Sprite;

	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.betweenas3.tweens.ITween;

	public class BetweenAS3Exam extends Sprite
	{
		public function BetweenAS3Exam()
		{
			var box:Sprite = new Sprite();
			box.graphics.beginFill(0x000000);
			box.graphics.drawRect(-10, -10, 20, 20);
			box.graphics.endFill();
			addChild(box);

			var t:ITween = BetweenAS3.tween(box, {x:200, y:200}, {x:0, y:0}, 0.6, Bounce.easeOut);
			t.play();
		}
	}
}

한가지 주의해야 할 점은, 다른 tweening 라이브러리는 메서드를 호출하면 바로 tweening이 실행되었지만, BetweenAS3는 play(); 메서드를 호출하지 않으면 tweening이 시작되지 않습니다.

아래는 tween메서드의 몇 가지 활용 예입니다.

// box의 x값을 현재 위치에서 200까지 이동
var t:ITween = BetweenAS3.tween(box, {x:200});
t.play();

// box의 x값을 100에서 200까지 이동
var t:ITween = BetweenAS3.tween(box, {x:200}, {x:100});
t.play();

// box의 x값을 100에서 현재 위치로 이동
var t:ITween = BetweenAS3.tween(box, null, {x:100});
t.play();

// ($를 붙이면 상대값으로 계산) box의 현재 x값이 50이라면 150(100+50)에서 250(200+50)까지 이동
var t:ITween = BetweenAS3.tween(box, {$x:200}, {$x:100});
t.play();

• Templates\ProjectFiles\AS2Project\Class.as.fdt
• Templates\ProjectFiles\AS3Project\Class.as.fdt

(설정파일이 들어 있는 폴더를 백업해 두셨다가 설치 후에 덮어씌우신 경우, 혹은 파일이 제대로 설치되지 않은 경우겠죠.)

Tools > Application Files 선택해서 FlashDevelop의 설정파일이 들어 있는 폴더를 열고,

Templates\ProjectFiles\AS2Project\Class.as.fdt 의 내용을 아래의 내용으로 수정.

$(Import)/**
$(CBI)* ...
$(CBI)* @author $(DefaultUser)
$(CBI)*/
$(Access)class $(FileNameWithPackage)$(Extends)$(Implements)$(CSLB){

	public function $(FileName)($(ConstructorArguments)) $(CSLB){
		$(Super)$(EntryPoint)
	}

}

Templates\ProjectFiles\AS3Project\Class.as.fdt 을 아래의 내용으로 수정해 주시면 됩니다.

package $(Package) $(CSLB){
$(Import)	/**
	$(CBI)* ...
	$(CBI)* @author $(DefaultUser)
	$(CBI)*/
	$(Access)class $(FileName)$(Extends)$(Implements)$(CSLB){

		public function $(FileName)($(ConstructorArguments)) $(CSLB){
			$(Super)$(EntryPoint)
		}

	}

}

http://www.flashdevelop.org/wikidocs/index.php?title=Features:Completion
에도 있는 내용이지만, 간단하게 정리해 보자.

일반적으로 배열을 사용할 경우,
아래와 같이 선언을 하고, 배열요소 뒤에 “.”를 찍어도 코드 자동완성을 사용할 수 없다.

var aryA:Array = ["a", "b", "c", "d"];
aryA[0].

강제적으로 Ctrl+Space를 눌러도 필요없는 코드 자동완성이 표시될 뿐…

하지만, 아래와 같은 방법으로 선언을 해주고, 배열요소 뒤에 “.”를 찍는 순간 코드 자동완성이 표시된다.

var aryB:/*String*/Array = ["a", "b", "c", "d"];
aryB[0].

여기서는 /*String*/ 즉, 문자열로 설정해 주었기 때문에 문자열에 해당하는 코드 자동완성이 표시되는 것.

단, 주의해야 할 부분은 Flash Player 10용 코딩을 한 뒤 Flash CS3에서 Test Movie로 확인은 불가능합니다. (Flash CS3에서 Test Movie 로 실행된 Flash Player는 버전이 다르기 때문일겁니다.)
Publish기능을 이용하면 되는데, File > Publish Settings 에서 Flash탭으로 이동 후 Version을 Flash Player 10으로 설정하고, Publish Preview(F12)를 이용하면 html파일을 통해 Flash Player 10용 코딩이 적용된 것을 확인 하실 수 있습니다.

Flash Player 10 standalone 을 사용해도 되겠죠?
참고로 Adobe Flash Player 10 – Debugger Versions 은 아래 페이지에서 다운로드 하시면 됩니다.
http://www.adobe.com/support/flashplayer/downloads.html#fp10

최근 FlashDevelop이 RC3부터 RC6까지 빠르게 버전업을 하더니 드디어 오늘 베타라는 이름을 벗어버리고, RTM으로 릴리즈 되었네요!

FlashDevelop 3.0.0 RTM 릴리즈의 자세한 내용 및 다운로드는 아래 링크에서~
http://www.flashdevelop.org/community/viewtopic.php?f=11&t=4921

이번 RTM은 RC2부터 RC6까지 완벽하게 호환된다고 하는군요.
그래도 기분상 이전 버전에 덮어서 설치하는 게 찝찝하신 분들은 이전 버전 삭제하기 전에 잊지 말고 백업해 놓으시길!!!
( 설정 폴더 C:\Documents and Settings\로그인아이디\Local Settings\Application Data\FlashDevelop )

Catalyst beta 는 다운로드 페이지에 30일동안 사용할 수 있는 시리얼넘버를 제공하고 있고,

Flash Builder 4 beta 의 경우는 일단 설치하면 30일동안 사용이 가능하고, 나중에 더 사용할 수 있는 키를 요청할 수 있는 것 같네요.
아래가 그런 내용이죠??

30-day Beta
These beta installers will time out in 30 days. If you are an existing Flex Builder 3 customer, Adobe will email you a serial number that will extend the beta so you can continue testing. You will receive this email 21 days after your download. If you do not receive the email and hold a valid Flex Builder 3 license, you can request the extension serial number here by entering your Flex Builder 3 serial number.

▶ TypingWeb – Online Typing Tutor

일단, 별도의 프로그램 설치가 필요 없습니다.
로그인 없이도 사용 가능하지만, 로그인을 하면 연습한 내용이 저장되기 때문에 마지막으로 연습한 곳에서부터 이어서 연습을 할 수 있고,
연습한 내용이 다양한 데이터(자기가 잘 틀리는 키가 무엇인지, 각 단계별 결과 등등)로 저장이 되기 때문에 나중에 보면 좋은 자료가 될 듯하네요.
타자연습 프로그램이라면 필수요소가 되어버린 문장 테스트나 게임도 할 수 있습니다.
그리고, 언어&키보드 설정을 통해 한글로 설정할 수 있는데…
아래 이미지를 보시면 아시겠지만, 그냥 단순번역 수준이라 그다지 도움이 되지는 않습니다.

아무리 그래도 왼쪽 이미지의 내용은 도무지 무슨 말인지 이해가 불가능하네요. (가끔 반말도 하고…)
“걱정 하지마, 이 모두는 거의 고통이다.”
이건 먼말인지…

그 외에도 구글에 Flash Builder로 검색하니 꽤 나오네요.

FlashDevelop을 주로 사용하니 큰 관심은 없지만…
뭐, 그냥 그렇다구요~~

우선, 샘플을 한 번 보시구요.

어때요? 깔끔한 게 쓸만하죠??

설정을 적용하기 전에, 혹시 새로 적용한 설정이 마음에 들지 않을지도 모르니깐 지금 사용하고 계시는 설정을 백업해 두세요.
Tools > Syntax Coloring 을 선택하시면 아래와 같은 설정창이 나옵니다.
하단에 두 개의 버튼이 있는데, 왼쪽은 현재설정을 파일로 저장하는 버튼이고, 오른쪽은 설정을 초기화하는 버튼입니다.

바로 다운로드 받고 실행해봤더니, 오우!! 기대 이상이더군요!!!
아래를 보시면 Firefox Ultimate Optimizer를 실행하기 전에는 메모리를 124,724K 나 먹던 놈이 Firefox Ultimate Optimizer를 실행하니 2,076K 로 줄어든게 보이시죠?

사용방법은 별거 없습니다.
아래 다운로드 링크를 통해서 파일 받으시고, 압축풀고, Firefox Ultimate Optimizer.exe 파일을 실행하면 트레이에서 실행이 됩니다.

그리고 설정이라고 한다면.. 뭐, 요정도?

다운로드 – Download firefox-ultimate-optimizer-11.zip
관련글 – http://www.ghacks.net/2008/01/12/firefox-ultimate-optimizer/

Vizual PV3D from Juxt Interactive on Vimeo.

Papervision3D가 가진 대부분의 기능을 사용할 수 있습니다만, 별도의 저장기능이 없고, XML형식으로만 Export를 할 수 있기 때문에(세션정보 저장용) VizualPV3D를 사용해서 특별한 결과물을 만들어 내는 것은 아직 불가능하네요.
다만, Papervision3D의 대부분의 기능을 사용할 수 있기 때문에 공부용으로 사용한다면 좋을 것 같네요.

다운로드
Download VizualPV3D.

원문 : http://www.stream.co.jp/company/press/2009/090507_01/

자세한 내용은 위의 원문을 보면 알 수 있지만, 여기서 내가 주목해야 할 부분은 물론 FlashPlayer의 보급율!!!
FlashPlayer의 버전별 보급율을 보면 10이 58.43%, 9가 38.33%, 7이 0.79%, 8이 0.76%
작년 10월쯤에 FlashPlayer10이 출시되었는데, 약 6개월만에 꽤 높은 보급율을 보여주고 있네요.
근데, 8보다 7이 미묘한 차이로 많군요..;;

- FlashPlayer 환경
2009년 2월 조사

2007년 9월 조사

한편, 마소의 Silverlight를 설치한 사용자는 전체의 24.33%.

- Silverlight의 보급율
2009년 2월 조사

개인적으로 플래시 디버깅툴로 Arthropod를 사용한다.
디버깅에 필요한 가장 기본적인 기능을 제공하기 때문에 가볍고, 또 깔끔한 UI때문인데, 가끔은 좀 더 상세한 디버깅을 필요로 할 경우가 있다.
그럴 때 필요한게 De MonsterDebugger가 아닌가 싶다.
De MonsterDebugger는 이름 그대로 괴물 같은 AIR기반의 디버거이다.
아직 많은 부분을 사용해보진 않았지만, 다양한 기능을 가지고 있는 것 같기에 일단 포스팅!!!

주요 기능은 Tree structure, Detailed traces, Live editing, Method testing이 있는데,
그 중에서 개인적으로 관심이 가는 기능은 Live editing, Method testing 이다.

Live editing – 디버거에서 속성값을 변경할 수 있다.
보통 플래시무비를 제작할 때 특정 속성값(X위치, Y위치, 알파값등등)의 적절한 값을 찾기 위해서는
해당 속성값을 변경하고, 그 결과를 테스트무비로 확인하는 과정을 수없이 반복하곤 했었는데,
이 Live editing기능을 사용하면 디버거에서 특정 속성값을 수정하면 바로 해당무비에 적용이 되기 때문에 간단하게 테스트가 가능하다.

Method testing – 디버거에서 함수를 실행할 수 있다.
Method testing은 Live editing처럼 디버거에서 함수를 실행하고, 그 결과를 볼 수 있다.
아래 그림처럼 디버거에서 getChildAt(0)을 실행하면 그 결과값을 확인할 수 있다.