Perl HowTo

Linksammlung: wxPerl

2013-04-02T06:45:00Z

"Kann man mit Perl plattformunabhängig GUIs schreiben, die gut aussehen?" ist eine typische Frage, die immer wieder am Perlstand auf den verschiedenen Open-Source Treffen, z.B. Chemnitzer Linuxtage, gestellt wird.

Hier noch ein Mal zum Nachlesen (und als SEO), was den Besuchern als Antwort präsentiert wird.

wxWidgets für Perl: wxPerl

wxPerl nutzt die wxWidgets zur Erzeugung betriebsystemunabhängiger graphischer Benutzer-Oberflächen (GUI).

Die wxWidgets bieten einen sehr grossen Funktionsumfang und natives Look and Feel auf jeder Plattform, d.h. unter Windows sieht das Programm wie ein richtiges Windows-Programm aus und unter Linux wie ein richtiges Linux-Programm.

Das kann man sich z.B. bei den Editoren Padre, the Perl IDE oder Kephra, die wxPerl nutzen, genauer ansehen.

Linksammlung wxPerl

Weitere interessante Links bitte einfach als Kommentar hinzufügen. Danke.

Siehe auch:

FLOSS-Weekly Episode 246: Interview mit Jeffrey Thalhammer - Pinto

2013-03-30T09:55:01Z

Pinto ist, vereinfacht gesagt, eine Software, mit der man sein eigenes CPAN Archiv mit definierten Versionen und Versionskontrolle erstellen und verwalten kann.

Twit.tv hat ein Interview mit Jeffrey Thalhammer, dem Erfinder von Pinto (und Perl::Critic) veröffentlicht.

Das Interview führt Randal Schwartz zusammen mit Aaron Newcomb.

Enjoy!

Siehe auch:

Via:

String::Dump - Was genau ist in einem String enthalten

2013-02-28T10:45:00Z

Manchmal steckt in einem String nicht das drin, was man erwartet, z.B. nicht druckbare oder UTF Zeichen.

String::Dump - Dump strings of characters (or bytes) for printing and debugging von Nick Patch vereinfacht das Debuggen solcher Probleme erheblich.

Bei Byte-Strings wird jedes Byte, bei Unicode-Strings wird jeder Codepoint ausgegeben.

String::Dump stellt sechs unterschiedliche Ausgabeformate über folgende Funktionen zur Verfügung.

dump_hex($string): Hexadecimal (base 16) mode
dump_dec($string): Decimal (base 10) mode
dump_oct($string): Octal (base 8) mode
dump_bin($string): Binary (base 2) mode
dump_names($string): Unicode character name mode
dump_codes($string): Unicode code point mode

Freunde der Kommandozeile sollten einen Blick auf mitgelieferte Tool dumpstr werfen.

Beispiel

Statt vieler Worte ein einfaches Beispiel:

#!/usr/bin/perl
use strict;
use warnings;

use utf8;

use String::Dump qw( :all );

my $string = 'Føø Bār';

print dump_hex($string), "\n";

print dump_dec($string), "\n";

print dump_oct($string), "\n";

print dump_bin($string), "\n";

print dump_names($string), "\n";

print dump_codes($string), "\n";

Das Programm erzeugt folgende Ausgabe:

46 F8 F8 20 42 101 72

70 248 248 32 66 257 114

106 370 370 40 102 401 162

1000110 11111000 11111000 100000 1000010 100000001 1110010

LATIN CAPITAL LETTER F, LATIN SMALL LETTER O WITH STROKE, LATIN SMALL LETTER O WITH STROKE, SPACE, LATIN CAPITAL LETTER B, LATIN SMALL LETTER A WITH MACRON, LATIN SMALL LETTER R

U+0046 U+00F8 U+00F8 U+0020 U+0042 U+0101 U+0072

Siehe auch:

CSS::Compressor - Schnelle und effiziente CSS Komprimierung

2012-12-27T10:51:14Z

CSS::Compressor - Perl extension for CSS minification, ein Perl-Port des bekannten Yahoo YUICompressor, bietet eine effiziente Kompression von CSS-Dateien und startet sehr viel schneller als sein Vorbild.

Das Modul CSS::Compressor wurde eigentlich für den internen Gebrauch von Booking.com entwickelt und nun als Open Source Software veröffentlicht.

Beispiel

Das folgende Beispielprogramm nimmt Dateinamen auf der Kommandozeile entgegen, liest den Inhalt der CSS-Datei mit File::Slurp in eine skalare Variable ein, komprimiert das CSS mit css_compress() und schreibt das Ergebnis in eine neue Datei.

#!/usr/bin/perl 
use warnings;
use strict;

use CSS::Compressor qw( css_compress );
use File::Slurp;

my @css_files = @ARGV;

foreach my $css_file (@css_files) {
    my $big      = read_file($css_file);
    my $small    = css_compress $big;
    my $out_file = $css_file;
    $out_file    =~ s#css$#min-css#is;
    write_file( $out_file, $small );
}

Aufruf/Verwendung:

$ chmod 755 css.pl
$ ./css.pl ./css_tests/*.css

Geschwindigkeitsvergleich

Die angepriesene deutliche Geschwindigkeitsverbesserung kann unter Linux einfach mit Bordmitteln nachgeprüft werden:

$ time ./css.pl ./css_tests/*.css
$ time yui-compressor -o '.css$:-min.css' ./css_tests/*.css

Auf meinen Testservern (Ubuntu 12.04) läuft CSS::Compressor 30 bis 40% schneller als YUICompressor.

Siehe auch:

Perl Advent(ures) 2012

2012-12-02T20:15:00Z

Es ist wieder so weit - Perl Adventskalender 2012 sind online:

Dann gibt auch noch sysadvent, ein Adventskalender für Sysadmins, der auch den ein oder anderen Beitrag mit Bezug auf Perl bietet.

Siehe auch:

Perl-News: Advent 2012 - viel Lesestoff

Algorithm::CheckDigits - Überprüfung von Nummerncodes

2012-11-14T21:15:00Z

Algorithm::CheckDigits - Perl extension to generate and test check digits von Mathias Weidner vereinfacht die Überprüfung von Nummerncodes, wie Umsatzsteuer-Identifikationsnummern, ISBNs, Betriebsnummern, Blutbeutel Eurocodes und zahlreichen mehr.

Dabei bietet Algorithm::CheckDigits eine konsistente Schnittstelle zu allen Berechnungsmethoden an.

Mit CheckDigits() wird das gewünschte Berechnungsverfahren gewählt und man erhält das passende Objekt zurück. Die Methode is_valid() prüft den Nummerncode, basenumber() liefert die Basiszahl und checkdigit() liefert die Prüfziffer für die Basiszahl zurück.

Alle verfügbaren Berechnungsmethoden auflisten

Eine Übersicht aller verfügbaren Berechnungsmethoden liefert method_list.

#!/usr/bin/perl
use strict;
use warnings;

use Algorithm::CheckDigits;

my @ml = Algorithm::CheckDigits->method_list();

foreach my $method ( @ml ) {
	print "$method\n";
}

Das Programm liefert folgende (deutlich gekürzte) Ausgabe:

2aus5
ahv_ch
amex
bahncard
betriebsnummer
blutbeutel
...
ustid_at
ustid_be
ustid_de
...
verhoeff
visa
wagonnr_br

Beispiel: Umsatzsteuer-Identifikationsnummer Deutschland

Das folgende Beispiel testet eine deutsche Umsatzsteuer-Identifikationsnummer.

#!/usr/bin/perl
use strict;
use warnings;

use Algorithm::CheckDigits;

my $ustid_de = CheckDigits('ustid_de');

#Umsatzsteuernummer: DE175903868
my $ustid = '175903868';

if ( $ustid_de->is_valid($ustid) ) {
    print "UmsatzsteuerID: $ustid ist okay.\n";
    my $cd = $ustid_de->checkdigit($ustid);
    my $bn = $ustid_de->basenumber($ustid);
    print "Checkdigit: $cd\n";
    print "Basiszahl: $bn\n";

}
else {
    print "UmsatzsteuerID: $ustid ist NICHT okay.\n";
}

Das Programm liefert folgende Ausgabe:

UmsatzsteuerID: 175903868 ist okay.
Checkdigit: 8
Basiszahl: 17590386

Umsatzsteuer-Identifikationsnummern aus Österreich lassen sich mit der Methode ustid_at checken. Ebenso lassen sich Umsatzsteuer-Identifikationsnummern aus den Niederlanden mittels ustid_nl testen.

Beispiel: ISBN-10

Das folgende Beispiel testet eine 10-stellige ISBN. 13-stellige ISBN lassen sich mit isbn13 prüfen.

#!/usr/bin/perl
use strict;
use warnings;

use Algorithm::CheckDigits;

my $isbn10_cd = CheckDigits('isbn');

my $isbn = '386899145X';

if ( $isbn10_cd->is_valid($isbn) ) {
    print "ISBN-10: $isbn ist okay.\n";
    my $cd = $isbn10_cd->checkdigit($isbn);
    my $bn = $isbn10_cd->basenumber($isbn);
    print "Checkdigit: $cd\n";
    print "Basiszahl: $bn\n";

}
else {
    print "ISBN-10: $isbn ist NICHT okay.\n";
}

Das Programm liefert folgende Ausgabe:

ISBN-10: 386899145X ist okay.
Checkdigit: X
Basiszahl: 386899145

Siehe auch

Sys::Hostname oder Net::Domain - Hostname ermitteln

2012-10-01T10:00:31Z

Der Hostname ist die eindeutige Bezeichnung eines Rechners in einem Netzwerk. Meist wird ein Fully Qualified Domain Name (FQDN) als Hostname verwendet. Bei Rechnern in einem LAN wird allerdings manchmal auch der Domain-Teil (hostdomain) weggelassen und nur der lokale Part (hostname) verwendet.

Die Ermittlung des Hostnamens ist nicht immer einfach, daher verwenden die beiden nachfolgend vorgestellen Module intern zahlreiche Methoden, um den Hostnamen herauszufinden.

Sys::Hostname

Sys::Hostname von David Sundstrom, seit Perl 5.6 Bestandteil der Standard-Distribution, stellt eine Funktion bereit: hostname().

#!/usr/bin/perl
use strict;
use warnings;

use Sys::Hostname;

print hostname(), "\n";

Das Programm liefert z.B. folgende Ausgabe:

server.example.net

oder auch einfach

server

Net::Domain

Net::Domain, seit Perl 5.73 Bestandteil der Standard-Distribution, von Graham Barr verwendet intern deutlich mehr Methoden als Sys::Hostname, um den FQDN des aktuellen Hosts zu ermittlen. Weiterhin werden auch Funktionen bereitgestellt, um den lokalen bzw. Domain-Teil zu ermitteln.

hostfqdn (): liefert den FQDN des aktuellen Hosts
domainname (): Ein Alias für hostfqdn
hostname (): liefert den lokalen Teil des FQDN
hostdomain (): liefert den Domain-Teil des FQDN

#!/usr/bin/perl
use strict;
use warnings;

use Net::Domain qw(hostname hostfqdn hostdomain);

print "Host FQDN:  ", hostfqdn , "\n";
print "Hostname:   ", hostname , "\n";
print "Hostdomain: ", hostdomain , "\n";

Das Programm liefert z.B. folgende Ausgabe:

Host FQDN:  server.example.net
Hostname:   server
Hostdomain: example.net

Siehe auch

Perldoc: perlfaq9
Perldoc: Sys::Hostname
The 2004 Perl Advent Calendar: Sys::Hostname
Perldoc: Net::Domain
CPAN: Sys::Hostname::Long
Wikipedia: Hostname
Wikipedia: Domain

Module::CoreList - welche Module werden eigentlich mit Perl ausgeliefert?

2012-07-16T19:45:08Z

Perl wird mit einer ansehnlichen Anzahl an Standardmodulen ausgeliefert.

Module::CoreList und das mitgelieferte Kommandozeilentool corelist - a commandline frontend to Module::CoreList bieten eine einfache, aber effektive Schnittstelle, um diesen Fundus zu durchsuchen.

Kommandozeile vs. Webinterface

In diesem Beitrag gehe ich kurz auf das Kommandozeilentool corelist ein.

Wer ein webbasiertes Interface bevorzugt, wird bei Webinterface: corelist - Find core modules in perl versions von Tina Müller (tinita) fündig.

Welche Perlversionen kennt die installierte Version von Module::Corelist?

Der Parameter -v zeigt ohne Angabe einer Perlversionsnummer eine Liste aller bekannten Perlversionen an.

$ corelist -v

Das liefert z.B. folgende (gekürzte) Ausgabe:

Module::CoreList has info on the following perl versions:
5
5.000
5.001
5.002
5.00307
5.004
5.00405
5.005
5.00503
5.00504
.........
v5.15.2
v5.15.3
v5.15.4
v5.15.5
v5.15.6
v5.15.7
v5.15.8
v5.15.9
v5.16.0
v5.17.0

Alle Coremodule einer bestimmten Perl-Version

Wird dem Parameter -v eine Perlversionsnummer angegeben, so wird eine Liste der mitgelieferten Core-Module und deren Versionsnummer angezeigt:

$ corelist -v 5.014002

oder

$ corelist -v 5.14.2

Das liefert z.B. folgende (gekürzte) Ausgabe:

The following modules were in perl 5.014002 CORE
AnyDBM_File                                      1.00
App::Cpan                                        1.5701
App::Prove                                       3.23
App::Prove::State                                3.23
App::Prove::State::Result                        3.23
App::Prove::State::Result::Test                  3.23
.........
utf8                                             1.09
vars                                             1.02
version                                          0.88
vmsish                                           1.02
warnings                                         1.12
warnings::register                               1.02

Wann wurde ein Modul erstmals in den Core aufgenommen?

Dazu übergibt man corelist einfach den Namen des gesuchten Moduls:

$ corelist parent

Das liefert folgende Ausgabe:

parent was first released with perl v5.10.1

In welchen Versionen liegt ein Core-Modul vor?

Der Parameter -a Name-des-Moduls liefert eine Liste der Perlversionen und der jeweils ausgelieferten Version des Coremodules

$ corelist -a parent

Das liefert z.B. folgende (gekürzte) Ausgabe:

parent was first released with perl v5.10.1
  v5.10.1    0.221     
  v5.11.0    0.223     
  v5.11.1    0.223 
  .........
  v5.15.9    0.225     
  v5.16.0    0.225     
  v5.17.0    0.225

Siehe auch:

MetaCPAN: Module::CoreList
CPAN: Module::CoreList
CPAN: corelist - a commandline frontend to Module::CoreList
Tina Müller (tinita): Webinterface: corelist - Find core modules in perl versions
Tina Müller (tinita) [blogs.perl.org] corelist web interface
PerlGeek: Small Perl Helpers
PerlMonks: Which core modules did Perl 5.x have?
PsyberMonkey: Perl - How to find out what Core Modules installed
Tyler Slijboom: Corelist and Perlbrew - 2 Perl command line tools for remote Perl work
CPAN: Module-Metadata-CoreList

Veranstaltung::Tipp - Europäische Perl-Konferenz 20.-22.08.2012 in Frankfurt/Main

2012-06-26T19:17:35Z

Die 13. Europäische Perl-Konferenz "YAPC::Europe" findet vom 20.-22. August 2012 an der Goethe-Universität Frankfurt/Main statt.

Die Europäische Perl-Konferenz "YAPC::Europe" ist die größte jährliche Konferenz für Anwender und Entwickler der dynamischen Open-Source-Programmiersprache Perl in Europa. In diesem Jahr wird sie von den Frankfurt Perlmongers e.V. ausgerichtet.

Modern Perl

Ein Schwerpunkt der Konferenz ist "Modern Perl". Dabei spielen Module wie Moose, eine neuartige Objektorientierung für Perl, und DBIx::Class als Schicht zwischen Anwendung und Datenbanken eine genauso wichtige Rolle wie die Web-Frameworks Catalyst, Dancer und Mojolicious.

Call for Papers

Die Konferenz steht und fällt mit den Vorträgen, die 5, 20 oder 40 Minuten lang sein können.

Alle Themen, die mit Perl oder dem Perl-Umfeld zu tun haben, können als Vorträge für die Konferenz interessant sein. Vorschläge müssen bis spätestens Sonntag, den 15. Juli 2012 als Abstract eingereicht werden. Der Abstract sollte in rund 2.000 Zeichen das Thema beschreiben.

Sponsoren

Die Konferenz bedeutet neben enormem zeitlichen auch hohen finanziellen Aufwand. Deshalb benötigen wir Unterstützung von Sponsoren, z.B. bei der Ausrichtung der Abendveranstaltung. Für mehr Informationen darüber, wie Sponsoren den Workshop unterstützen können, steht Renée Bäcker (sponsoring@yapc2012.de) zur Verfügung.

Preise

Wie in den Jahren zuvor sind die Preise für die Teilnahme niedrig: Für Studenten liegt der Beitrag bei 50 €, für Privatpersonen bei 110 € und für Firmenteilnehmer bei 450 € für die gesamte Konferenz. Bis zum 8. Juli gibt es für Privatpersonen einen Frühbucherrabatt, so dass das Ticket nur 80 € kostet

Siehe auch

Lese::Tipp - PerlyBook - CPAN Modul Dokumentation als E-Book

2012-05-30T20:00:00Z

Renée Bäcker hat vor einigen Wochen den Dienst PerlyBook in Leben gerufen, der die POD-Dokumentation von CPAN-Modulen in die E-Book Formate EPUB und MOBI umwandeln kann.

Ich habe PerlyBook auf mehreren androiden Tablets mit verschiedenen E-Book-Readern ausprobiert und bin begeistert. Funktioniert einwandfrei.

Screenshots

Statt vieler Worte ein paar Screenshots - so sieht es aus:

Seitenansicht (Hochformat):

Inhaltsverzeichnis:

Siehe auch:

PerlNews: Modul-Dokumentation als E-Book
Perl-Blog: Modul-Dokumentation als E-Book
PerlyBook

Serverumzug Perl-Howto.de abgeschlossen

2012-05-30T18:30:00Z

Der Umzug von Perl-Howto.de auf einen eigenen schnelleren Server ist geschafft.

Ich werde ab jetzt auch wieder mehr Beiträge in diesem Blog veröffentlichen

Neue Features

Captchas für Kommentare ohne Anmeldung - das Spamaufkommen ist bereits jetzt drastisch gesunken
Kommentarautoren können sich jetzt auch mit OpenID und Google Accounts anmelden - eine oft gewünschte Funktionalität

Falls jemandem (m/w) ein Fehler auffüllt, dann bitte einfach als Kommentar melden. Danke.

Net::NTP - Antwortpakete eines NTP-Servers einfach dekodieren

2012-03-22T19:15:00Z

"Das Network Time Protocol (NTP) ist ein Standard zur Synchronisierung von Uhren in Computersystemen über paketbasierte Kommunikationsnetze. NTP verwendet das verbindungslose Transportprotokoll UDP. NTP wurde speziell entwickelt, um eine zuverlässige Zeitgabe über Netzwerke mit variabler Paketlaufzeit zu ermöglichen." Quelle: Wikipedia: Network Time Protocol.

NTP-Server versenden Antworten im NTP Message Format, die sich mit Net::NTP - Perl extension for decoding NTP server responses von Ask Bjørn Hansen einfach dekodieren lassen.

Beispiel:

Net::NTP exportiert eine einzige Funktion, get_ntp_response(), die als optionalen Parameter auch die Adresse eines NTP-Server annimmt und liefert einen Hash zurück, dessen Schlüssel die einzelnen Abschnitte des NTP Antwort Pakets enthält.

#!/usr/bin/perl
use strict;
use warnings;

use Net::NTP qw(get_ntp_response);

my $ntp_server = shift ||  'ptbtime1.ptb.de';

my %response = get_ntp_response( $ntp_server );

my @response_keys = sort keys %response;

foreach my $response_key ( @response_keys ) {
	print "$response_key: $response{ $response_key }\n";
}

Das Programm liefert folgende Ausgabe:

Leap Indicator: 0
Mode: 4
Originate Timestamp: 1332443226.50195
Poll Interval: 0.0000
Precision: -21
Receive Timestamp: 1332443226.90883
Reference Clock Identifier: PTB
Reference Timestamp: 1332443217.35515
Root Delay: 0
Root Dispersion: 0.0000
Stratum: 1
Transmit Timestamp: 1332443226.90883
Version Number: 3

Die Schlüssel des %response ensprechen den einzelnen Feldern des NTP Antwortpakets:

                           1                   2                   3
       0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0 1
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |LI | VN  |Mode |    Stratum    |     Poll      |   Precision   |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                          Root Delay                           |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                       Root Dispersion                         |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                     Reference Identifier                      |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                                                               |
      |                   Reference Timestamp (64)                    |
      |                                                               |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                                                               |
      |                   Originate Timestamp (64)                    |
      |                                                               |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                                                               |
      |                    Receive Timestamp (64)                     |
      |                                                               |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                                                               |
      |                    Transmit Timestamp (64)                    |
      |                                                               |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                 Key Identifier (optional) (32)                |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
      |                                                               |
      |                                                               |
      |                 Message Digest (optional) (128)               |
      |                                                               |
      |                                                               |
      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+

Quelle: RFC 2030

Siehe auch

Perl Advent(ures) 2011

2011-12-01T17:15:00Z

Es ist wieder so weit - Perl Adventskalender 2011 sind online:

Via:

PreshBlog: Perl Advent Calendars for 2011

Perl in the Cloud - OpenShift Express by Red Hat - Installation, Initialisierung und Konfiguration

2011-11-24T11:22:45Z

OpenShift by Red Hat soll die Entwicklung von Open-Source-Anwendungen für die Cloud vereinfachen. Dieser Plattform-as-a-Service stellt eine Infrastruktur für verschiedene Programmiersprachen und Web-Frameworks zur Verfügung.

Red Hat unterscheidet zwischen den Produktvarianten Express, Flex und Power.

Die kostenlose Express Variante (Registrierung erforderlich) erlaubt u.a. die Verwendung der dynamischen Programmiersprache Perl in Version 5.10.1, der Datenbanken MySQL in Version 5.1 oder SQLite in Version 3 und (ganz wichtig) die Installation von CPAN-Modulen.

Die bekannten und beliebten Perl Web-Frameworks Dancer, Mojolicious und Catalyst können verwendet werden.

Schritt für Schritt

Dieser Beitrag geht zuerst Schritt für Schritt durch die Installation, Initialisierung und Konfiguration von OpenShift Express. Danach wird ein betont einfaches, aber nützliches Perl-Programm erstellt und gezeigt, wie dieses in die Cloud ausgeliefert (deployed) wird.

Registrierung

Zur Verwendung von OpenShift Express ist eine Registrierung mit einer gültigen E-Mail-Adresse erfoderlich. Alternativ kann auch ein bestehender RHN-Account verwendet werden.

Installation der Client-Tools

OpenShift funktioniert unter Mac OSX, Linux und Windows - für diesen Beitrag verwende ich CentOS 6 (64-Bit in einer eigenen virtuellen Maschine).

Für die Client-Tools bietet RedHat eine eigenes YUM-Repository an, das wie folgt installiert wird.

# wget https://openshift.redhat.com/app/repo/openshift.repo
# mv openshift.repo /etc/yum.repos.d

Damit alle Paket-Abhänigkeiten aufgelöst werden, musste ich auch die EPEL- und RPMForge-Repositories hinzufügen.

Nun können die Client-Tools installiert werden:

# yum install rhc

Initialisierung

Alle Apps eines Users werden in einen eigenen Namensraum (Domain) installiert. Apps sind dann nach dem Schema http://$app-$domain.rhcloud.com öffentlich erreichbar. Dazu gleich mehr.

Das Kommando rhc-create-domain erzeugt einen neuen Namensraum, die Konfigurationsdatei express.conf und SSH-Schlüssel (libra_id_rsa) zur Git-Authentifizierung.

$ rhc-create-domain -n yourdomain -l user@example.com
Password: <user password>

Generating Openshift Express ssh key to /home/UserName/.ssh/libra_id_rsa
Generating public/private RSA key pair.
Created directory '/home/UserName/.ssh'.
Enter passphrase (empty for no passphrase):
Enter same passphrase again:
Your identification has been saved in /home/UserName/.ssh/libra_id_rsa.
Your public key has been saved in /home/UserName/.ssh/libra_id_rsa.pub.
.
.
Contacting https://openshift.redhat.com
Adding rhlogin to /home/UserName/.openshift/express.conf
Creation successful

You may now create an application.  Please make note of your local config file
in /home/UserName/.openshift/express.conf which has been created and populated for
you.

Jetzt noch Git (minimal) konfigurieren

$ git config --global user.name "Your Name"
$ git config --global user.email you@example.com

und dann kann endlich die erste App erstellt werden.

Appgerüst erzeugen

Das Kommando rhc-create-app erzeugt das Gerüst der neuen App. Über die Option -a wird der Name der Applikation angegeben. Die Option -t legt den Typ der Applikation, hier perl-5.10, fest. Typen werden in der Dokumentation auch gerne als cartridge bezeichnet.

$ rhc-create-app -a X1 -t perl-5.10 
Password: 

Attempting to create remote application space: X1
Now your new domain name is being propagated worldwide (this might take a minute)...
Pulling new repo down
Warning: Permanently added 'x1-thomasfahle.rhcloud.com,184.73.107.7' (RSA) to the list of known hosts.
Confirming application 'X1' is available
  Attempt # 1

Success!  Your application 'X1' is now published here:

      http://X1-thomasfahle.rhcloud.com/

The remote repository is located here:

    ssh://ce3eb6cc3b1942a2a61a76db6ff63274@X1-thomasfahle.rhcloud.com/~/git/X1.git/

To make changes to 'X1', commit to X1/.

Successfully created application: X1

Die neu erstellte Applikation mit dem Namen X1 innerhalb des Namensraumes thomasfahle ist sofort unter der URL http://x1-thomasfahle.rhcloud.com/ erreichbar.

Wer lieber seine eigene Domain verwenden möchte und über einen eigenen Nameserver verfügt, kann einen DNS Alias einrichten.

Orientierung im Gelände

Die neu erstellte Applikation befindet sich im Verzeichnis $app, hier X1.

$ tree X1
X1
|-- deplist.txt
|-- libs
|-- misc
|-- perl
|   |-- health_check.pl
|   `-- index.pl
`-- README

Das Verzeichnis perl ist die DocumentRoot der Webapp. Alle hier abgelegten Dateien sind öffentlich. Die Datei index.pl dient als DirectoryIndex.

Die Datei deplist.txt nimmt eine Liste der zu installierenden CPAN-Module auf, pro Zeile ein Modul ohne Versionsnummer.
Beispiel:

Test::Base
YAML
Dancer
Plack::Handler::Apache2

Das Verzeichnis misc ist nicht öffentlich und kann für eigene Zwecke genutzt werden.

Das Verzeichnis libs ist ebenfalls nicht öffentlich und dient als Speicherort für eigene Module.

Sinn und Zweck der Datei health_check.pl ist mir nicht ganz klar geworden.

Weiterhin gibt es noch ein verstecktes Verzeichnis .openshift zur Steuerung des Build-Prozesses. Dazu später mehr.

Das erste Programm: Umgebungsvariablen

Einige Konfigurationseinstellungen, z.B. für Datenbanken, sind als Umgebungsvariablen abgelegt.

Daher erstellen wir als erstes einfaches Beispiel keine Hallo-Welt-App, sondern eine nützliche App, welche die Umgebungsvariablen anzeigt.

Das Programm wird unter dem Namen printenv.pl im Ordner perl abgelegt.

#!/usr/bin/perl
use strict;
use warnings;

#  printenv -- demo CGI program which just prints its environment
print "Content-type: text/plain\n\n";

foreach my $key ( sort( keys(%ENV) ) ) {
    my $val = $ENV{$key};
    $val =~ s|\n|\\n|g;
    $val =~ s|"|\\"|g;
    print qq~$key = $val\n~;
}
exit();

Zur Veröffentlichung (Deployment) der App verwendet OpenShift Git. Sobald die Datei hinzugefügt und commited wurde, kann diese per git push in die Cloud ausgeliefert werden.

$ git add printenv.pl
$ git commit -m 'Umgebungsvariablen App'
$ git push

Counting objects: 6, done.
Compressing objects: 100% (4/4), done.
Writing objects: 100% (4/4), 594 bytes, done.
Total 4 (delta 1), reused 0 (delta 0)
remote: Stopping application...
remote: Waiting for stop to finish
remote: Done
remote: Running .openshift/action_hooks/pre_build
remote: strict is up to date. (1.04)
remote: skipping F/FL/FLORA/perl-5.15.4.tar.gz
remote: Running .openshift/action_hooks/build
remote: Running .openshift/action_hooks/deploy
remote: Starting application...
remote: Done
remote: Running .openshift/action_hooks/post_deploy
To ssh://ce3eb6cc3b1942a2a61a76db6ff63274@X1-thomasfahle.rhcloud.com/~/git/X1.git/
   ee74341..e31f2ec  master -> master

Das Programm ist nun unter der URL http://x1-thomasfahle.rhcloud.com/printenv.pl erreichbar.

Hinweis: Alle Daten innerhalb des Git-Repositories werden dabei auf dem OpenShift Express Server zunächst gelöscht und dann neu eingespielt.

Hinweis: Da Umgebungsvariablen auch Benutzernamen und Passwörter enthalten können, sollte dieses Programm nicht auf dem Cloud-Server verbleiben.

Zum Bau und zur Auslieferung der Applikation werden die Programme im Ordner .openschift/action_hooks/ ausgeführt. Um sich die Umgebungsvariablen anzeigen zu lassen, genügt es in die Datei build die Anweisung export einzufügen. Dann werden die Umgebungsvariablen bei jedem push angezeigt.

$ cat .openshift/action_hooks/build 
#!/bin/bash
# This is a simple build script and will be executed on your CI system if 
# available.  Otherwise it will execute while your application is stopped
# before the deploy step.  This script gets executed directly, so it
# could be python, php, ruby, etc.
export

Eigene Umgebungsvariablen können derzeit nicht gesetzt werden.

Logfiles

Das Kommando rhc-tail-files ermöglicht den Zugriff auf die Logdateien auf dem Cloud-Server.

$ rhc-tail-files -a X1 
Password: 

Attempting to tail files: X1/logs/*
Use ctl + c to stop

==> X1/logs/error_log-20111122-000000-EST <==
[Tue Nov 22 16:43:18 2011] [notice] Apache/2.2.15 (Unix) mod_perl/2.0.4 Perl/v5.10.1 configured -- resuming normal operations

==> X1/logs/access_log-20111122-000000-EST <==
xx.xxx.xxx.IP - - [22/Nov/2011:16:47:04 -0500] "GET /printenv.pl HTTP/1.0" 200 2323 "-" "Mozilla/5.0 (X11; U; Linux i686; de; rv:1.9.2.24) Gecko/20111107 Ubuntu/10.04 (lucid) Firefox/3.6.24"

Der Zugriff auf die error_log Dateien erleichert das Debuggen erheblich.

Snapshots

Das Kommando rhc-snapshot erstellt einen Snapshot der Applikation und liefert diesen als gezippte tar Datei zurü:

$ rhc-snapshot  -a X1 
Password: 

Pulling down a snapshot to X1.tar.gz

Stopping application...
Waiting for stop to finish
Done
Creating and sending tar.gz
Starting application...
Done

Wenn man die Datei X1.tar.gz auspackt, sieht man alle Verzeichnisse und Dateien der Applikation.

$ tar -xzvf X1.tar.gz
$ cd app-verzeichnis

$ tree
.
|-- git
|   `-- X1.git
|       |-- branches
|       |-- config
|       |-- description
|       |-- HEAD
|       |-- hooks
|       |   |-- applypatch-msg.sample
|       |   |-- commit-msg.sample
|       |   |-- post-commit.sample
|       |   |-- post-receive
|       |   |-- post-receive.sample
|       |   |-- post-update.sample
|       |   |-- pre-applypatch.sample
|       |   |-- pre-commit.sample
|       |   |-- prepare-commit-msg.sample
|       |   |-- pre-rebase.sample
|       |   |-- pre-receive
|       |   `-- update.sample
|       |-- info
|       |   |-- exclude
|       |   `-- refs
|       |-- objects
|       |   |-- 0a
|       |   |   `-- bed1546ab3d6aee5b42c68f57100f52949b4bf
|       |   |-- 10
|       |   |   `-- cd54466b8f66bb40d6c50ab5519bf7727e51dd
|       |   |-- 1d
|       |   |   `-- b60ffa4e6b41be6ed92a6a2b3343c70b301fb6
|       |   |-- 2f
|       |   |   `-- a0243ca6abb34233618e9ea809871be855a225
|       |   |-- 40
|       |   |   |-- 0b36608e5e4405636bf7394c546ec18de53252
|       |   |   `-- c24d558d8a1196d4170f56182b8f69fbe6741f
|       |   |-- 5e
|       |   |   `-- 1c48b299eb8c1fd204b69e520236d3a2a3217e
|       |   |-- 6a
|       |   |   `-- e37b40a1cd342e2661bdf06b65fc4731e1af1e
|       |   |-- 9b
|       |   |   `-- 594ba566f5036940fd00dfeca9cd38e51579a8
|       |   |-- a5
|       |   |   `-- 7d1f5806d714a998130b9517a4240de0c39fe3
|       |   |-- b5
|       |   |   `-- 3bde9fe6346b3d54d39b9d970308cc25080cbe
|       |   |-- c0
|       |   |   `-- df17bb0b3dbdb4da6c06ad6fe4e070e3061485
|       |   |-- c1
|       |   |   `-- d6344439cdc822df02c54bb39aabb5ccd4a7de
|       |   |-- d5
|       |   |   `-- 64d0bc3dd917926892c55e3706cc116d5b165e
|       |   |-- df
|       |   |   `-- 8d841a9e8c1afd175e0061bb7b762d708b0c58
|       |   |-- e3
|       |   |   `-- 1f2ec741b91b2d4ddc9500991cc660a8cf037d
|       |   |-- e6
|       |   |   `-- 9de29bb2d1d6434b8b29ae775ad8c2e48c5391
|       |   |-- ed
|       |   |   `-- 5eb993715da4af89ce517eedb2c3879994e10e
|       |   |-- ee
|       |   |   `-- 74341ac408153e9bfe02fe55669533ccdfdbba
|       |   |-- f1
|       |   |   `-- 25e7fa5f3603669e173695b284d170ddd7b62f
|       |   |-- info
|       |   |   `-- packs
|       |   `-- pack
|       |       |-- pack-e8aca9b5d216bb7c5a7ac884d5cdcb6c0a9faabe.idx
|       |       `-- pack-e8aca9b5d216bb7c5a7ac884d5cdcb6c0a9faabe.pack
|       |-- packed-refs
|       `-- refs
|           |-- heads
|           |   `-- master
|           `-- tags
`-- X1
    |-- ci
    |-- conf
    |   `-- magic -> /etc/httpd/conf/magic
    |-- conf.d
    |-- data
    |-- logs
    |   |-- access_log-20111122-000000-EST
    |   |-- access_log-20111123-000000-EST
    |   |-- error_log-20111122-000000-EST
    |   `-- error_log-20111123-000000-EST
    |-- modules -> /usr/lib64/httpd/modules
    |-- perl5lib
    |-- repo -> runtime/repo
    |-- run
    |-- runtime
    |   `-- repo
    |       |-- deplist.txt
    |       |-- libs
    |       |-- misc
    |       |-- perl
    |       |   |-- health_check.pl
    |       |   |-- index.pl
    |       |   `-- printenv.pl
    |       `-- README
    `-- tmp

45 directories, 53 files

Persistent Storage

Wie oben bereits erwähnt, werden bei der Auslieferung (git push) alle Dateien, die sich innerhalb des Git-Repositories befinden, auf dem Cloud-Server gelöscht und neu eingespielt.

Persistente Daten, z.B. SQLite Dateien, müssen daher ausserhalb des Git-Repositories auf dem Server aufbewahrt werden. Dazu stellt OpenShift Express den Ordner data zur Verfügung.

Der Pfad zum Ordner data kann aus der Umgebungsvariablen OPENSHIFT_DATA_DIR ermittelt werden.

#!/usr/bin/perl
use strict;
use warnings;

print "Content-type: text/plain\n\n";

my $data_dir = $ENV{OPENSHIFT_DATA_DIR};
my $file = 'test.txt';

open (OUT, ">" , "$data_dir/$file" ) or die $!;

for ( 1 .. 10 ) {
        print OUT "$_\n";
}
close(OUT) or die $!;
exit();

Die im Ordner data gespeicherten Daten lassen sich per rhc-snapshot vom Cloud-Server holen.

$ tree
.
|-- ci
|-- conf
|   `-- magic -> /etc/httpd/conf/magic
|-- conf.d
|-- data
|   `-- test.txt
|-- logs
|   |-- access_log-20111122-000000-EST
|   |-- access_log-20111123-000000-EST
|   |-- error_log-20111122-000000-EST
|   `-- error_log-20111123-000000-EST
|-- modules -> /usr/lib64/httpd/modules
|-- perl5lib
|-- repo -> runtime/repo
|-- run
|-- runtime
|   `-- repo
|       |-- deplist.txt
|       |-- libs
|       |-- misc
|       |-- perl
|       |   |-- health_check.pl
|       |   |-- index.pl
|       |   |-- printenv.pl
|       |   |-- read.pl
|       |   `-- write.pl
|       `-- README
`-- tmp

Siehe auch

OpenShift by Red Hat
OpenShift Express
User Guide - Using OpenShift Express to manage your applications in the cloud
Frequently Asked Questions > OpenShift FAQ
OpenShift Knowledge Base - How to onboard a Perl application
OpenShift Beispiele auf GitHub
OpenShift Knowledge Base - How to deploy the Perl Dancer framework on OpenShift Express
openshift / dancer-example
OpenShift Knowledge Base - Installing OpenShift Express client tools on Mac OSX, Linux, and Windows
man 5 express.conf - configuration file for OpenShift Express
man 1 rhc-create-domain - creates a new OpenShift Express domain namespace with a user
man 1 rhc-create-app - creates a new hosted application at rhcloud.com
man 1 rhc-tail-files - Tail files from remote running applications in real-time
man 1 rhc-user-info - Displays information about a user on the rhcloud.com system
man 1 rhc-chk - Diagnoses the connection between this client and the OpenShift servers
man 1 rhc-ctl-app - Control an existing rhcloud.com application
man 1 rhc-snapshot - Pulls down an application snapshot as gzipped tarfile
OpenShift Knowledge Base - I have deployed my app, but I don't like telling people to visit <my_app>-<my_username>.rhcloud.com. How can I set up my own domain name to point to my app?
OpenShift Knowledge Base - Redirecting your server to OpenShift Express with mod_rewrite
Linux Magazin - Cloud-Küche - Red Hat Open Shift: Plattform für Webentwickler und Hoster

WWW::Google::PageRank - Google Pagerank für Websites abfragen

2011-11-21T17:17:53Z

WWW::Google::PageRank von Yuri Karaban ermittelt den Google Pagerank für Websites.

Pagerank ermitteln: get()

Die Methode get() liefert im skalaren Kontext den Pagerank, im Listenkontext den Pagerank und zusätzlich ein HTTP::Response Objekt zum Debuggen zurück.

Beispiel: get() im skalaren Kontext

#!/usr/bin/perl
use strict;
use warnings;

use WWW::Google::PageRank;

my $pr = WWW::Google::PageRank->new( host => 'toolbarqueries.google.de' );

my @urls = qw!
  http://perl-howto.de
  http://yahoo.de
  http://web.de
  !;

foreach my $url (@urls) {
    print "URL: $url ", scalar( $pr->get($url) ), "\n";
}

Das Programm liefert folgende Ausgabe:

URL: http://perl-howto.de 4
URL: http://yahoo.de 8
URL: http://web.de 7

Beispiel: get() im Listenkontext

#!/usr/bin/perl
use strict;
use warnings;

use WWW::Google::PageRank;

my $pr = WWW::Google::PageRank->new( host => 'toolbarqueries.google.de' )
  or die $!;

my @urls = qw!
  http://perl-howto.de
  http://yahoo.de
  http://web.de
  http://example.tld
  !;

# Debug
foreach my $url (@urls) {
    print "URL: $url ";

    my ( $pagerank, $response ) = $pr->get($url);

    if ( defined $pagerank ) {
        print "PageRank: $pagerank\n";
    }
    else {
        print "Fehler: ", $response->status_line, "\n";
        warn $response->as_string, "\n";
    }
}

Das Programm liefert folgende Ausgabe (die lange XML-Ausgabe des as_string() habe ich weggelassen):

URL: http://perl-howto.de PageRank: 4
URL: http://yahoo.de PageRank: 8
URL: http://web.de PageRank: 7
URL: http://example.tld Fehler: 403 Forbidden